arm 2440編譯空間安排

可能性判斷1：編譯生成的main.o沒有被完全從nandflash中copy到sdram中運行。
分析head.s文件，也即硬件初始化過程，nandflash的4k由硬件自動從nandflash拷貝到sram中，然后有一個拷貝4k的sram到sdram中，但是nandflash中4k以后的就沒人管了哦?。?！因此需要一個函數(shù)copy nandflash的4k以后的代碼到sdram中。

解決辦法1： 將nandflash初始化函數(shù)和nandflash讀函數(shù)都固化進init.c中，調(diào)試。搞定

主要head.s 代碼如下，其他代碼可以根據(jù)調(diào)試信息增添即可難度降低：

@******************************************************************************
@ File: head.S
@ 功能: 設(shè)置SDRAM，將程序復制到SDRAM，然后跳到SDRAM繼續(xù)執(zhí)行
@******************************************************************************

.extern main
.text
.global _start
_start:
@******************************************************************************
@ 中斷向量，本程序中，除Reset和HandleIRQ外，其它異常都沒有使用
@******************************************************************************
b Reset

@ 0x04: 未定義指令中止模式的向量地址
HandleUndef:
b HandleUndef

@ 0x08: 管理模式的向量地址，通過SWI指令進入此模式
HandleSWI:
b HandleSWI

@ 0x0c: 指令預取終止導致的異常的向量地址
HandlePrefetchAbort:
b HandlePrefetchAbort

@ 0x10: 數(shù)據(jù)訪問終止導致的異常的向量地址
HandleDataAbort:
b HandleDataAbort

@ 0x14: 保留
HandleNotUsed:
b HandleNotUsed

@ 0x18: 中斷模式的向量地址
b HandleIRQ

@ 0x1c: 快中斷模式的向量地址
HandleFIQ:
b HandleFIQ

Reset:
ldr sp, =4096 @ 設(shè)置棧指針，以下都是C函數(shù)，調(diào)用前需要設(shè)好棧
bl disable_watch_dog @ 關(guān)閉WATCHDOG，否則CPU會不斷重啟
bl clock_init @ 設(shè)置MPLL，改變FCLK、HCLK、PCLK
bl memsetup @ 設(shè)置存儲控制器以使用SDRAM
bl init_nandflash @ 初始化NAND Flash
@ 復制代碼到SDRAM中
ldr r0, =0x30000000 @ 1. 目標地址 = 0x30000000，這是SDRAM的起始地址
mov r1, #4096 @ 2. 源地址 = 4096，運行地址在SDRAM中的代碼保存在NAND Flash 4096地址開始處
mov r2, #64*1024 @ 3. 復制長度 = 16K，對于本實驗，這是足夠了
bl CopyCode2SDRAM @ 調(diào)用C函數(shù)CopyCode2SDRAM

msr cpsr_c, #0xd2 @ 進入中斷模式
ldr sp, =0x31000000 @ 設(shè)置中斷模式棧指針

msr cpsr_c, #0xdf @ 進入系統(tǒng)模式
ldr sp, =0x34000000 @ 設(shè)置系統(tǒng)模式棧指針，

ldr lr, =ret_initirq @ 設(shè)置返回地址
ret_initirq:
msr cpsr_c, #0x5f @ 設(shè)置I-bit=0，開IRQ中斷

ldr lr, =halt_loop @ 設(shè)置返回地址
ldr pc, =main @ 調(diào)用main函數(shù)
halt_loop:
b halt_loop

HandleIRQ:
sub lr, lr, #4 @ 計算返回地址
stmdb sp!, { r0-r12,lr } @ 保存使用到的寄存器
@ 注意，此時的sp是中斷模式的sp
@ 初始值是上面設(shè)置的4096

ldr lr, =int_return @ 設(shè)置調(diào)用IRQ_Handle函數(shù)后的返回地址
//ldr pc, =Timer0_Handle @ 調(diào)用中斷服務(wù)函數(shù)，在interrupt.c中
// ldr pc, =IRQ_Handle @ 調(diào)用中斷分發(fā)函數(shù)，在interrupt.c中
// ldr pc, =EINT_Handle @ 調(diào)用中斷分發(fā)函數(shù)，在interrupt.c中
int_return:
ldmia sp!, { r0-r12,pc }^ @ 中斷返回, ^表示將spsr的值復制到cpsr