一步步寫(xiě)STM32 OS【三】PendSV與堆棧操作

　　一、什么是PendSV

　　PendSV是可懸起異常，如果我們把它配置最低優(yōu)先級(jí)，那么如果同時(shí)有多個(gè)異常被觸發(fā)，它會(huì)在其他異常執(zhí)行完畢后再執(zhí)行，而且任何異常都可以中斷它。更詳細(xì)的內(nèi)容在《Cortex-M3 權(quán)威指南》里有介紹，下面我摘抄了一段。

　　OS 可以利用它“緩期執(zhí)行”一個(gè)異常——直到其它重要的任務(wù)完成后才執(zhí)行動(dòng) 作。懸起 PendSV 的方法是：手工往 NVIC的 PendSV懸起寄存器中寫(xiě) 1。懸起后，如果優(yōu)先級(jí)不夠 高，則將緩期等待執(zhí)行。

　　PendSV的典型使用場(chǎng)合是在上下文切換時(shí)(在不同任務(wù)之間切換)。例如，一個(gè)系統(tǒng)中有兩個(gè)就緒的任務(wù)，上下文切換被觸發(fā)的場(chǎng)合可以是：

　　1、執(zhí)行一個(gè)系統(tǒng)調(diào)用

　　2、系統(tǒng)滴答定時(shí)器(SYSTICK)中斷，(輪轉(zhuǎn)調(diào)度中需要)

　　讓我們舉個(gè)簡(jiǎn)單的例子來(lái)輔助理解。假設(shè)有這么一個(gè)系統(tǒng)，里面有兩個(gè)就緒的任務(wù)，并且通過(guò)SysTick異常啟動(dòng)上下文切換。但若在產(chǎn)生 SysTick 異常時(shí)正在響應(yīng)一個(gè)中斷，則 SysTick異常會(huì)搶占其 ISR。在這種情況下，OS是不能執(zhí)行上下文切換的，否則將使中斷請(qǐng)求被延遲，而且在真實(shí)系統(tǒng)中延遲時(shí)間還往往不可預(yù)知——任何有一丁點(diǎn)實(shí)時(shí)要求的系統(tǒng)都決不能容忍這 種事。因此，在 CM3 中也是嚴(yán)禁沒(méi)商量——如果 OS 在某中斷活躍時(shí)嘗試切入線(xiàn)程模式，將觸犯用法fault異常。

　　為解決此問(wèn)題，早期的 OS 大多會(huì)檢測(cè)當(dāng)前是否有中斷在活躍中，只有在無(wú)任何中斷需要響應(yīng) 時(shí)，才執(zhí)行上下文切換(切換期間無(wú)法響應(yīng)中斷)。然而，這種方法的弊端在于，它可以把任務(wù)切 換動(dòng)作拖延很久(因?yàn)槿绻麚屨剂?nbsp;IRQ，則本次 SysTick在執(zhí)行后不得作上下文切換，只能等待下 一次SysTick異常)，尤其是當(dāng)某中斷源的頻率和SysTick異常的頻率比較接近時(shí)，會(huì)發(fā)生“共振”， 使上下文切換遲遲不能進(jìn)行?，F(xiàn)在好了，PendSV來(lái)完美解決這個(gè)問(wèn)題了。PendSV異常會(huì)自動(dòng)延遲上下文切換的請(qǐng)求，直到 其它的 ISR都完成了處理后才放行。為實(shí)現(xiàn)這個(gè)機(jī)制，需要把 PendSV編程為最低優(yōu)先級(jí)的異常。如果 OS檢測(cè)到某 IRQ正在活動(dòng)并且被 SysTick搶占，它將懸起一個(gè) PendSV異常，以便緩期執(zhí)行 上下文切換。

　　使用 PendSV 控制上下文切換個(gè)中事件的流水賬記錄如下：

　　1. 任務(wù) A呼叫 SVC來(lái)請(qǐng)求任務(wù)切換(例如，等待某些工作完成)

　　2. OS接收到請(qǐng)求，做好上下文切換的準(zhǔn)備，并且懸起一個(gè) PendSV異常。

　　3. 當(dāng) CPU退出 SVC后，它立即進(jìn)入 PendSV，從而執(zhí)行上下文切換。

　　4. 當(dāng) PendSV執(zhí)行完畢后，將返回到任務(wù) B，同時(shí)進(jìn)入線(xiàn)程模式。

　　5. 發(fā)生了一個(gè)中斷，并且中斷服務(wù)程序開(kāi)始執(zhí)行

　　6. 在 ISR執(zhí)行過(guò)程中，發(fā)生 SysTick異常，并且搶占了該 ISR。

　　7. OS執(zhí)行必要的操作，然后懸起 PendSV異常以作好上下文切換的準(zhǔn)備。

　　8. 當(dāng) SysTick退出后，回到先前被搶占的 ISR中，ISR繼續(xù)執(zhí)行

　　9. ISR執(zhí)行完畢并退出后，PendSV服務(wù)例程開(kāi)始執(zhí)行，并且在里面執(zhí)行上下文切換

　　10. 當(dāng) PendSV執(zhí)行完畢后，回到任務(wù) A，同時(shí)系統(tǒng)再次進(jìn)入線(xiàn)程模式。

　　我們?cè)趗COS的PendSV的處理代碼中可以看到：

　　OS_CPU_PendSVHandler

　　CPSID I ; 關(guān)中斷

　　;保存上文

　　;.......................

　　;切換下文

　　CPSIE I ;開(kāi)中斷

　　BX LR ;異常返回

　　它在異常一開(kāi)始就關(guān)閉了中端，結(jié)束時(shí)開(kāi)啟中斷，中間的代碼為臨界區(qū)代碼，即不可被中斷的操作。PendSV異常是任務(wù)切換的堆棧部分的核心，由他來(lái)完成上下文切換。PendSV的操作也很簡(jiǎn)單，主要有設(shè)置優(yōu)先級(jí)和觸發(fā)異常兩部分：

　　NVIC_INT_CTRL EQU 0xE000ED04 ; 中斷控制寄存器

　　NVIC_SYSPRI14 EQU 0xE000ED22 ; 系統(tǒng)優(yōu)先級(jí)寄存器(優(yōu)先級(jí)14).

　　NVIC_PENDSV_PRI EQU 0xFF ; PendSV優(yōu)先級(jí)(最低). NVIC_PENDSVSET EQU 0x10000000 ; PendSV觸發(fā)值

　　; 設(shè)置PendSV的異常中斷優(yōu)先級(jí)

　　LDR R0, =NVIC_SYSPRI14

　　LDR R1, =NVIC_PENDSV_PRI

　　STRB R1, [R0] ; 觸發(fā)PendSV異常

　　LDR R0, =NVIC_INT_CTRL

　　LDR R1, =NVIC_PENDSVSET

　　STR R1, [R0]

　　二、堆棧操作

　　Cortex M4有兩個(gè)堆棧寄存器，主堆棧指針(MSP)與進(jìn)程堆棧指針(PSP)，而且任一時(shí)刻只能使用其中的一個(gè)。MSP為復(fù)位后缺省使用的堆棧指針，異常永遠(yuǎn)使用MSP，如果手動(dòng)開(kāi)啟PSP，那么線(xiàn)程使用PSP，否則也使用MSP。怎么開(kāi)啟PSP?

　　MSR PSP, R0 ; Load PSP with new process SP

　　ORR LR, LR, #0x04 ; Ensure exception return uses process stack

　　很容易就看出來(lái)了，置LR的位2為1，那么異常返回后，線(xiàn)程使用PSP。

　　寫(xiě)OS首先要將內(nèi)存分配搞明白，單片機(jī)內(nèi)存本來(lái)就很小，所以我們當(dāng)然要斤斤計(jì)較一下。在OS運(yùn)行之前，我們首先要初始化MSP和PSP，OS_CPU_ExceptStkBase是外部變量，假如我們給主堆棧分配1KB(256*4)的內(nèi)存即OS_CPU_ExceptStk[256],則OS_CPU_ExceptStkBase=&OS_CPU_ExceptStk[256-1]。

　　EXTERN OS_CPU_ExceptStkBase

　　;PSP清零，作為首次上下文切換的標(biāo)志

　　MOVS R0, #0

　　MSR PSP, R0

　　;將MSP設(shè)為我們?yōu)槠浞峙涞膬?nèi)存地址

　　LDR R0, =OS_CPU_ExceptStkBase

　　LDR R1, [R0]

　　MSR MSP, R1

　　然后就是PendSV上下文切換中的堆棧操作了，如果不使用FPU，則進(jìn)入異常自動(dòng)壓棧xPSR，PC，LR，R12，R0-R3，我們還要把R4-R11入棧。如果開(kāi)啟了FPU，自動(dòng)壓棧的寄存器還有S0-S15，還需吧S16-S31壓棧。

　　MRS R0, PSP

　　SUBS R0, R0, #0x20 ;壓入R4-R11

　　STM R0, {R4-R11}

　　LDR R1, =Cur_TCB_Point ;當(dāng)前任務(wù)的指針

　　LDR R1, [R1]

　　STR R0, [R1] ; 更新任務(wù)堆棧指針

　　出棧類(lèi)似，但要注意順序

　　LDR R1, =TCB_Point ;要切換的任務(wù)指針

　　LDR R2, [R1]

　　LDR R0, [R2] ; R0為要切換的任務(wù)堆棧地址

　　LDM R0, {R4-R11} ; 彈出R4-R11

　　ADDS R0, R0, #0x20

　　MSR PSP, R0 ;更新PSP

　　三、OS實(shí)戰(zhàn)

　　新建os_port.asm文件，內(nèi)容如下：

　　NVIC_INT_CTRL EQU 0xE000ED04 ; Interrupt control state register.

　　NVIC_SYSPRI14 EQU 0xE000ED22 ; System priority register (priority 14).

　　NVIC_PENDSV_PRI EQU 0xFF ; PendSV priority value (lowest).

　　NVIC_PENDSVSET EQU 0x10000000 ; Value to trigger PendSV exception.

　　RSEG CODE:CODE:NOROOT(2)

　　THUMB

　　EXTERN g_OS_CPU_ExceptStkBase

　　EXTERN g_OS_Tcb_CurP

　　EXTERN g_OS_Tcb_HighRdyP

　　PUBLIC OSStart_Asm

　　PUBLIC PendSV_Handler

　　PUBLIC OSCtxSw

　　OSCtxSw

　　LDR R0, =NVIC_INT_CTRL

　　LDR R1, =NVIC_PENDSVSET

　　STR R1, [R0]

　　BX LR ; Enable interrupts at processor level

　　OSStart_Asm

　　LDR R0, =NVIC_SYSPRI14 ; Set the PendSV exception priority

　　LDR R1, =NVIC_PENDSV_PRI

　　STRB R1, [R0]

　　MOVS R0, #0 ; Set the PSP to 0 for initial context switch call

　　MSR PSP, R0

　　LDR R0, =g_OS_CPU_ExceptStkBase ; Initialize the MSP to the OS_CPU_ExceptStkBase

　　LDR R1, [R0]

　　MSR MSP, R1

　　LDR R0, =NVIC_INT_CTRL ; Trigger the PendSV exception (causes context switch)

　　LDR R1, =NVIC_PENDSVSET

　　STR R1, [R0]

　　CPSIE I ; Enable interrupts at processor level

　　OSStartHang

　　B OSStartHang ; Should never get here

　　PendSV_Handler

　　CPSID I ; Prevent interruption during context switch

　　MRS R0, PSP ; PSP is process stack pointer

　　CBZ R0, OS_CPU_PendSVHandler_nosave ; Skip register save the first time

　　SUBS R0, R0, #0x20 ; Save remaining regs r4-11 on process stack

　　STM R0, {R4-R11}

　　LDR R1, =g_OS_Tcb_CurP ; OSTCBCur->OSTCBStkPtr = SP;

　　LDR R1, [R1]

　　STR R0, [R1] ; R0 is SP of process being switched out

　　; At this point, entire context of process has been saved

　　OS_CPU_PendSVHandler_nosave

　　LDR R0, =g_OS_Tcb_CurP ; OSTCBCur = OSTCBHighRdy;

　　LDR R1, =g_OS_Tcb_HighRdyP

　　LDR R2, [R1]

　　STR R2, [R0]

　　LDR R0, [R2] ; R0 is new process SP; SP = OSTCBHighRdy->OSTCBStkPtr;

　　LDM R0, {R4-R11} ; Restore r4-11 from new process stack

　　ADDS R0, R0, #0x20

　　MSR PSP, R0 ; Load PSP with new process SP

　　ORR LR, LR, #0x04 ; Ensure exception return uses process stack

　　CPSIE I

　　BX LR ; Exception return will restore remaining context

　　END

　　main.c內(nèi)容如下：

　　#include "stdio.h"

　　#define OS_EXCEPT_STK_SIZE 1024

　　#define TASK_1_STK_SIZE 1024

　　#define TASK_2_STK_SIZE 1024

　　typedef unsigned int OS_STK;

　　typedef void (*OS_TASK)(void);

　　typedef struct OS_TCB

　　{

　　OS_STK *StkAddr;

　　}OS_TCB,*OS_TCBP;

　　OS_TCBP g_OS_Tcb_CurP;

　　OS_TCBP g_OS_Tcb_HighRdyP;

　　static OS_STK OS_CPU_ExceptStk[OS_EXCEPT_STK_SIZE];

　　OS_STK *g_OS_CPU_ExceptStkBase;

　　static OS_TCB TCB_1;

　　static OS_TCB TCB_2;

　　static OS_STK TASK_1_STK[TASK_1_STK_SIZE];

　　static OS_STK TASK_2_STK[TASK_2_STK_SIZE];

　　extern void OSStart_Asm(void);

　　extern void OSCtxSw(void);

　　void Task_Switch()

　　{

　　if(g_OS_Tcb_CurP == &TCB_1)

　　g_OS_Tcb_HighRdyP=&TCB_2;

　　else

　　g_OS_Tcb_HighRdyP=&TCB_1;

　　OSCtxSw();

　　}

　　void task_1()

　　{

　　printf("Task 1 Running!!!n");

　　Task_Switch();

　　printf("Task 1 Running!!!n");

　　Task_Switch();

　　}

　　void task_2()

　　{

　　printf("Task 2 Running!!!n");

　　Task_Switch();

　　printf("Task 2 Running!!!n");

　　Task_Switch();

　　}

　　void Task_End(void)

　　{

　　printf("Task Endn");

　　while(1)

　　{}

　　}

　　void Task_Create(OS_TCB *tcb,OS_TASK task,OS_STK *stk)

　　{

　　OS_STK *p_stk;

　　p_stk = stk;

　　p_stk = (OS_STK *)((OS_STK)(p_stk) & 0xFFFFFFF8u);

　　*(--p_stk) = (OS_STK)0x01000000uL; //xPSR

　　*(--p_stk) = (OS_STK)task; // Entry Point

　　*(--p_stk) = (OS_STK)Task_End; // R14 (LR)

　　*(--p_stk) = (OS_STK)0x12121212uL; // R12

　　*(--p_stk) = (OS_STK)0x03030303uL; // R3

　　*(--p_stk) = (OS_STK)0x02020202uL; // R2

　　*(--p_stk) = (OS_STK)0x01010101uL; // R1

　　*(--p_stk) = (OS_STK)0x00000000u; // R0

　　*(--p_stk) = (OS_STK)0x11111111uL; // R11

　　*(--p_stk) = (OS_STK)0x10101010uL; // R10

　　*(--p_stk) = (OS_STK)0x09090909uL; // R9

　　*(--p_stk) = (OS_STK)0x08080808uL; // R8

　　*(--p_stk) = (OS_STK)0x07070707uL; // R7

　　*(--p_stk) = (OS_STK)0x06060606uL; // R6

　　*(--p_stk) = (OS_STK)0x05050505uL; // R5

　　*(--p_stk) = (OS_STK)0x04040404uL; // R4

　　tcb->StkAddr=p_stk;

　　}

　　int main()

　　{

　　g_OS_CPU_ExceptStkBase = OS_CPU_ExceptStk + OS_EXCEPT_STK_SIZE - 1;

　　Task_Create(&TCB_1,task_1,&TASK_1_STK[TASK_1_STK_SIZE-1]);

　　Task_Create(&TCB_2,task_2,&TASK_2_STK[TASK_1_STK_SIZE-1]);

　　g_OS_Tcb_HighRdyP=&TCB_1;

　　OSStart_Asm();

　　return 0;

　　}

　　編譯下載并調(diào)試：

　　在此處設(shè)置斷點(diǎn)

　　此時(shí)寄存器的值，可以看到R4-R11正是我們給的值，單步運(yùn)行幾次，可以看到進(jìn)入了我們的任務(wù)task_1或task_2，任務(wù)里打印信息，然后調(diào)用Task_Switch進(jìn)行切換，OSCtxSw觸發(fā)PendSV異常。

　　IO輸出如下：

　　至此我們成功實(shí)現(xiàn)了使用PenSV進(jìn)行兩個(gè)任務(wù)的互相切換。之后，我們使用使用SysTick實(shí)現(xiàn)比較完整的多任務(wù)切換。