硬盤(pán)存儲(chǔ)在單片機(jī)上的應(yīng)用

8031 系列單片機(jī)是應(yīng)用非常廣泛的CPU，但隨著控制領(lǐng)域不斷智能化和復(fù)雜化，程序與數(shù)據(jù)空間可能遠(yuǎn)遠(yuǎn)大于64K字節(jié)的限制。在8031系列單片機(jī)上擴(kuò)展硬盤(pán)接口，使存儲(chǔ)容量只受到硬盤(pán)容量的限制，可以達(dá)到Gbyte級(jí)的容量。在需要大容量存儲(chǔ)的應(yīng)用場(chǎng)合，如數(shù)據(jù)庫(kù)、圖像處理、采樣分析等場(chǎng)合，有著廣泛的應(yīng)用。

一、基本知識(shí)

1． IDE接口

在PC上，硬盤(pán)通過(guò)IDE40芯的扁平非屏蔽電纜與主板連接，數(shù)據(jù)和命令在其上異步傳輸。詳細(xì)的信號(hào)描述請(qǐng)參照Information Technology -AT Attachment with Packet Interface - 6(ATA/ATAPI-6)協(xié)議。

2． 硬盤(pán)寄存器描述

與硬盤(pán)通信是通過(guò)IO寄存器來(lái)完成的，訪問(wèn)硬盤(pán)上的寄存器是由CS0FX，CS3FX，A2，A1，A0來(lái)譯碼完成的。硬盤(pán)的寄存器分為命令寄存器組和控制寄存器組。

詳細(xì)說(shuō)明如下：

1） 數(shù)據(jù)寄存器，在CS3FX為高電平,CS0FX,A2,A1,A0為低電平時(shí)選通，其地址為0x8000。單片機(jī)通過(guò)讀寫(xiě)該寄存器與硬盤(pán)交互數(shù)據(jù)。

2） 錯(cuò)誤信息寄存器，在CS3FX，A0為高電平,CS0FX,A2,A1為低電平時(shí)選通，其地址為0x8001。該寄存器為只讀，寄存器位如置1代表不同的錯(cuò)誤信息。

3）屬性寄存器，在CS3FX，A0為高電平,CS0FX,A2,A1為低電平時(shí)選通，其地址為0x8001。該寄存器為只寫(xiě)，對(duì)該寄存器的操作可使硬盤(pán)工作在不同的模式。由于8031單片機(jī)為8位的數(shù)據(jù)總線，而硬盤(pán)默認(rèn)為16位IO，需要對(duì)屬性寄存器寫(xiě)0x01，使其工作在8位總線模式。

4） 扇區(qū)數(shù)目寄存器，在CS3FX,A1為高電平,CS0FX,A2,A0為低電平時(shí)選通，其地址為0x8002。其值表示需對(duì)硬盤(pán)讀寫(xiě)的扇區(qū)數(shù)目，注意對(duì)硬盤(pán)的操作都是以扇區(qū)位單位，每個(gè)扇區(qū)包含512個(gè)字節(jié)，即每次對(duì)硬盤(pán)的數(shù)據(jù)讀寫(xiě)都是512個(gè)字節(jié)的倍數(shù)。

5） LBA低8位地址寄存器，在CS3FX,A1,A0為高電平,CS0FX,A2為低電平時(shí)選通，其地址為0x8003。本文中對(duì)硬盤(pán)的操作是以LBA模式進(jìn)行，即硬盤(pán)上的存儲(chǔ)扇區(qū)映射成連續(xù)的邏輯塊地址。要使能LBA模式，需要對(duì)模式寄存器的第6位置1。

6） LBA 地址8－15位寄存器，在CS3FX,A2為高電平,CS0FX,A1,A0為低電平時(shí)選通，其地址為0x8004。LBA地址共28位表示。

7） LBA 地址16－23位寄存器，在CS3FX,A2,A0為高電平,CS0FX,A1為低電平時(shí)選通，其地址為0x8005。

8）模式寄存器，在CS3FX,A2,A1為高電平,CS0FX,A0為低電平時(shí)選通，參照原理圖1，其地址為0x8006。其低4位為L(zhǎng)BA地址的24－ 27位，第4位為主從硬盤(pán)選擇位，若連接J1，則硬盤(pán)設(shè)為主設(shè)備，相應(yīng)的第4位應(yīng)為0；若斷開(kāi)J1，則硬盤(pán)為從設(shè)備，相應(yīng)的第4位應(yīng)置1。

9） 狀態(tài)寄存器，在CS3FX, A2, A1, A0為高電平,CS0FX為低電平時(shí)選通，其地址為0x8007。該寄存器為只讀。其中第7位若為1，表示硬盤(pán)處于忙狀態(tài)，第3位若為1，表示數(shù)據(jù)準(zhǔn)備好，等待傳輸。詳細(xì)的檢驗(yàn)程序請(qǐng)參照所附的程序。

10） 命令寄存器，在CS3FX, A2, A1, A0為高電平,CS0FX為低電平時(shí)選通，其地址為0x8007。該寄存器為只寫(xiě)。注意硬盤(pán)的命令有帶參數(shù)和不帶參數(shù)兩種，在具有參數(shù)的命令操作時(shí)，需要首先寫(xiě)入所有的參數(shù)到各個(gè)寄存器，最后寫(xiě)命令寄存器。

二、硬件連接

8031單片機(jī)與硬盤(pán)的連接如圖1所示。A0 A1 A2經(jīng)74LS373鎖存后，連接到硬盤(pán)的A0 A1 A2腳，因其工作在8位模式，硬盤(pán)的高8位數(shù)據(jù)線懸空。

J1用來(lái)選擇主從硬盤(pán)，在連接J1時(shí)，該硬盤(pán)位主硬盤(pán)，否則為從硬盤(pán)。8031應(yīng)檢測(cè)P1.0上的電平，相應(yīng)地設(shè)置模式寄存器的第4位。

P1.1用于硬復(fù)位硬盤(pán)，在低電平時(shí)有效。因8031不支持DMA模式，硬盤(pán)工作于PIO模式，所以DMA請(qǐng)求與應(yīng)答信號(hào)懸空。所附軟件工作于查詢模式，中斷請(qǐng)求信號(hào)懸空。

在硬盤(pán)讀寫(xiě)操作時(shí)，DASP腳為低電平，相應(yīng)的LED指示燈亮。

三、相應(yīng)軟件

以對(duì)硬盤(pán)寫(xiě)入和讀出一個(gè)扇區(qū)為例，說(shuō)明8031對(duì)硬盤(pán)的操作。流程圖如圖2所示。

現(xiàn)結(jié)合具體程序分析。為便于程序閱讀，定義了如下的符號(hào)：

ReadSctr EQU 20h
WriteSctr EQU 30h
Data_Reg EQU 8000h ; 數(shù)據(jù)寄存器，可讀寫(xiě)
Error_Reg EQU 8001h ; 錯(cuò)誤信息寄存器，只讀
Features EQU 8001h ; 屬性寄存器，只寫(xiě)
Sectr_Cnt EQU 8002h ; 扇區(qū)數(shù)目寄存器，可讀寫(xiě)
LBA0_7 EQU 8003h ; LBA低8位地址寄存器，可讀寫(xiě)
LBA8_15 EQU 8004h ; LBA地址8－15位寄存器，可讀寫(xiě)
LBA16_24 EQU 8005h ; LBA 地址16－23位寄存器，可讀寫(xiě)
Drv_Head EQU 8006h ; 模式寄存器，可讀寫(xiě)
Status EQU 8007h ; 狀態(tài)寄存器, 只讀
Command EQU 8007h ; 命令寄存器，只寫(xiě)

1） 檢測(cè)主從硬盤(pán)并設(shè)置相應(yīng)的模式寄存器子程序

功能為檢測(cè)跳線設(shè)置，對(duì)模式寄存器寫(xiě)對(duì)應(yīng)值，并置為L(zhǎng)BA模式。
Init:
mov B, #11100000b ; D4=0 默認(rèn)為主硬盤(pán)，LBA模式
jnb P1.0, master ; 若P1.0=0,為主硬盤(pán)
mov B, #11110000b ; D4=1 為對(duì)從硬盤(pán)操作
master:
mov dptr, #Drv_Head ; 對(duì)模式寄存器寫(xiě)入
mov a, B ;
movx @dptr, a
ret

2） 忙狀態(tài)檢測(cè)子程序

功能為，讀狀態(tài)寄存器，在BUSY＝0和沒(méi)有錯(cuò)誤時(shí)，返回A=0和C＝0。
Busy:
mov dptr, #status; 讀狀態(tài)寄存器
movx a, @dptr
jb acc.7, Busy; 在BUSY為高時(shí)，等待
jb acc.0, errors; 若第0位為1，表示有錯(cuò)誤產(chǎn)生，跳轉(zhuǎn)到error處理
clr a ; A C 為0表示非忙，沒(méi)有錯(cuò)誤
clr C ;
ret ;
errors:
mov dptr, #Error_Reg
movx a, @dptr; A中值表示錯(cuò)誤指示
setb C ; C為1，表示有錯(cuò)誤產(chǎn)生
ret

3） 等待數(shù)據(jù)準(zhǔn)備好子程序

功能為，讀狀態(tài)寄存器，在BUSY＝0，DRQ＝1，沒(méi)有錯(cuò)誤時(shí)，返回A=0和C＝0。
WaitDRQ:
mov dptr, #status; 讀狀態(tài)寄存器
movx a, @dptr
jb acc.7, WaitDRQ ; 在BUSY為高時(shí)，等待
jnb acc.3, WaitDRQ ; 在第3位DRQ為0時(shí), 等待
jb acc.0, errors ; 若第0位為1，表示有錯(cuò)誤產(chǎn)生，跳轉(zhuǎn)到error處理
clr a
clr C ; A C 為0表示非忙，沒(méi)有錯(cuò)誤，數(shù)據(jù)已準(zhǔn)備好
ret

4） 置硬盤(pán)工作在8位數(shù)據(jù)IO模式子程序

功能設(shè)置硬盤(pán)屬性，使其工作在8位模式，與8031的8位數(shù)據(jù)總線配合。
Enable8bit:
acall Busy
mov dptr, #Features
mov a, #01h ; 使能8位模式
movx @dptr, a
mov dptr, #COMMAND
mov a, #0EFh; 0xEF為設(shè)置硬盤(pán)屬性命令
movx @dptr, a
ret

5） 填充硬盤(pán)寄存器子程序

入口為R2（扇區(qū)數(shù)目）,R3（LBA地址的b0－b7）,R4(LBA地址的b8-b15), R5(LBA地址的b16－b23) ,R6(低4位為L(zhǎng)BA地址的b24－b27), R7（命令字）

功能為將R2－R7中值寫(xiě)入到硬盤(pán)寄存器組。
Function:
acall Busy; 調(diào)用Busy子程序，如三.2）所述
mov dptr, #Sectr_Cnt; 扇區(qū)數(shù)目寄存器
mov a, R2 ; R2中值為扇區(qū)數(shù)目
movx @dptr, a
mov dptr, #LBA0_7; LBA地址的b0－b7寄存器
mov a, R3 ; R3中值為L(zhǎng)BA地址的b0－b7
movx @dptr, a
mov dptr, #LBA8_15; LBA地址的b8-b15寄存器
mov a, R4 ; R4中值為L(zhǎng)BA地址的b8-b15
movx @dptr, a
mov dptr, #LBA16_24; LBA地址的b16－b23寄存器
mov a, R5 ; R5中值為L(zhǎng)BA地址的b16－b23
movx @dptr, a
mov dptr, #Drv_Head; 模式寄存器
mov a, R6 ; R6中值為低4位為L(zhǎng)BA地址的b24－b27
anl a, #00001111b
orl a, B;B在Init子程序中已賦值.
movx @dptr, a
mov dptr, #command; 命令寄存器
mov a, R7 ; R7中值為命令字
movx @dptr, a
ret

6） 寫(xiě)扇區(qū)子程序

假定對(duì)LBA地址為0x0A的扇區(qū)寫(xiě)，
Write_Sctr:
mov R2, #1 ; 對(duì)R2-R7填入適當(dāng)值，調(diào)用Function
mov R3, #0Ah ;
mov R4, #0
mov R5, #0
mov R6, #0
mov R7, #WriteSctr
acall Function
acall WaitDRQ
acall Write512
ret
Write512:
mov R0, #high(message) ; 取需寫(xiě)入信息的高位地址
mov R1, #low(message) ; 取需寫(xiě)入信息的低位地址
mov R7, #2 ; 512字節(jié) = 2 * 256
mov R6, #0
write:
mov dph, R0 ;
mov dpl, R1
clr a
movc a, @a+dptr ; 讀取信息的內(nèi)容
inc dptr ; 指針指向下一個(gè)字節(jié)地址
mov R0, dph ;
mov R1, dpl
mov DPTR, #Data_Reg ; 數(shù)據(jù)寄存器
movx @dptr, a ; 寫(xiě)一個(gè)字節(jié)到硬盤(pán)
djnz R6, write
djnz R7, write ; 循環(huán)直到512個(gè)字節(jié)全部寫(xiě)完
ret

四、總結(jié)

由于篇幅所限，不詳細(xì)介紹對(duì)硬盤(pán)的讀操作，其流程類(lèi)似于寫(xiě)操作。感興趣讀者可對(duì)照ATA協(xié)議規(guī)范，編寫(xiě)相應(yīng)的驅(qū)動(dòng)程序。對(duì)硬盤(pán)操作的ATA命令很多，可以通過(guò)ATA命令進(jìn)行電源管理，讀取硬盤(pán)參數(shù)，進(jìn)行多個(gè)扇區(qū)的讀寫(xiě)操作。欲詳細(xì)了解對(duì)硬盤(pán)的操作，可參照最新的ATA－6協(xié)議。本文中，對(duì)硬盤(pán)的訪問(wèn)采用輪詢模式，也可以使對(duì)硬盤(pán)的訪問(wèn)工作于中斷模式，使其在BUSY＝0或DRQ＝1時(shí)觸發(fā)中斷。

在8031上，硬盤(pán)只可以工作在8位IO，PIO模式，依照本文的思路，可使硬盤(pán)工作于任何嵌入式系統(tǒng)中，工作于DMA模式或16位IO模式。